Задача: доработать стандартные правила конвертации данных из ЗиУП для Украины 2.1 в Бухгалтерию для Украины 2.0: необходимо добавить в конвертацию кадровые документы и сделать правильную выгрузку ведомостей по выплате зарплаты.
Документ "Прием на работу"
Документ "Прием на работу в организацию" в конфигурации ЗиУП имеет табличную часть и позволяет за один раз принять несколько сотрудников. В конфигурации Бухгалтерия для Украины 2.0 такой документ содержит другую структуру реквизитов и позволяет в одном документе принять на работу только одного сотрудника.
Т. о. мы будем обращаться к табличной части "РаботникиОрганизации" и каждую его строку конвертировать в отдельный документ. Значит, необходимо отключить поиск по уникальному идентификатору, иначе конвертация будет работать не корректно. Для выгрузки данных используем механизм запросов, встроенный в "Конвертация данных 2.1":
///Запрос "Прием на работу в организацию"
ВЫБРАТЬ
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Дата,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Организация,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Комментарий,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.ФизЛицо КАК ФизическоеЛицо,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.ПодразделениеОрганизации КАК Подразделение,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Должность,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.ДатаПриема,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник.ВидЗанятости КАК ВидЗанятости,
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.ОсновныеНачисления.(
ФизЛицо КАК ФизическоеЛицо,
ВидРасчета КАК Начисление,
Показатель1 КАК Размер,
) КАК ОсновныеНачисления
ИЗ
Документ.ПриемНаРаботуВОрганизацию.РаботникиОрганизации КАК ПриемНаРаботуВОрганизациюРаботникиОрганизации
ГДЕ
ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Проведен
И ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Организация = &Организация
И &ДопУсловиеПКО "ПриемНаРаботу"
Табличную часть "Начисления" будем формировать в структуре "Входящие данные" в событии ПКО "Перед выгрузкой:
РежимЗаписи = "Проведение";
ВходящиеДанные = Новый Структура("Начисления");
ВходящиеДанные.Начисления = Новый ТаблицаЗначений;
ВходящиеДанные.Начисления.Колонки.Добавить("Начисление");
ВходящиеДанные.Начисления.Колонки.Добавить("Размер");
Для Каждого Строка из Источник.ОсновныеНачисления Цикл
Если Строка.ФизическоеЛицо <> Источник.ФизическоеЛицо Тогда
Продолжить;
КонецЕсли;
НовСтрока = ВходящиеДанные.Начисления.Добавить();
ЗаполнитьЗначенияСвойств(НовСтрока, Строка);
КонецЦикла;Реквизит "КатегорияЕСВ" будем формировать из регистра сведений "ВзносыВФондыРаботниковОрганизаций". В событии "Перед выгрузкой":
Значение = Справочники.Налоги.ПустаяСсылка();
Запрос = Новый Запрос;
Запрос.Текст = "
|ВЫБРАТЬ РАЗЛИЧНЫЕ ПЕРВЫЕ 1
| ВзносыВФондыРаботниковОрганизаций.Налог
|ИЗ
| РегистрСведений.ВзносыВФондыРаботниковОрганизаций КАК ВзносыВФондыРаботниковОрганизаций
|ГДЕ
| ВзносыВФондыРаботниковОрганизаций.Актуальность
| И ВзносыВФондыРаботниковОрганизаций.Активность
| И ВзносыВФондыРаботниковОрганизаций.Регистратор = &Регистратор
| И ВзносыВФондыРаботниковОрганизаций.Сотрудник = &Сотрудник
| И ВзносыВФондыРаботниковОрганизаций.Налог НЕ В (&СписокНалогов)
|";
СписокНалогов = Новый СписокЗначений;
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничные);
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничныеИнвалиды50);
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничныеИнвалиды);
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничныеУТОГ);
Запрос.УстановитьПараметр("Регистратор", Источник.Ссылка);
Запрос.УстановитьПараметр("Сотрудник", Источник.Сотрудник);
Запрос.УстановитьПараметр("СписокНалогов", СписокНалогов);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Значение = Выборка.Налог;
КонецЦикла;
Если НЕ ЗначениеЗаполнено(Значение) Тогда
Значение = Справочники.Налоги.ЕСВФОТРаботники;
КонецЕсли;Документ "Кадровое перемещение"
Запрос для выгрузки данных из документа "Кадровое перемещение" принципиально не отличается от предыдущего документа:
//Запрос "Кадровое перемещение"
ВЫБРАТЬ
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка.Дата,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка.ОбособленноеПодразделениеКуда КАК ОбособленноеПодразделениеКуда,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка.Организация,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка.Комментарий,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.ФизЛицо КАК ФизическоеЛицо,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.ПодразделениеОрганизации КАК Подразделение,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Должность,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.ДатаНачала,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Сотрудник,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Сотрудник.ВидЗанятости КАК ВидЗанятости,
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка.ОсновныеНачисления.(
ФизЛицо КАК ФизическоеЛицо,
Действие КАК Действие,
ВидРасчета КАК Начисление,
Показатель1 КАК Размер,
) КАК ОсновныеНачисления
ИЗ
Документ.КадровоеПеремещениеОрганизаций.РаботникиОрганизации КАК КадровоеПеремещениеОрганизацийРаботникиОрганизации
ГДЕ
КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка.Проведен
И КадровоеПеремещениеОрганизацийРаботникиОрганизации.Ссылка.Организация = &Организация
И &ДопУсловиеПКО "КадровыйПеревод"
В Бухгалтерии 2.0 документ "Кадровый перевод" имеет два флага "Изменить начисления" и "Изменить подразделение и должность". От них зависит по каким регистрам документ будет делать движения. Следовательно, перед выгрузкой документа нужно определить, какая именно операция производится в кадровом перемещении и проставить нужные флаги. Событие ПКО "Перед выгрузкой":
РежимЗаписи = "Проведение";
ВходящиеДанные = Новый Структура("Начисления, ИзменитьНачисления, ИзменитьПодразделениеИДолжность");
ВходящиеДанные.ИзменитьНачисления = Ложь;
ВходящиеДанные.ИзменитьПодразделениеИДолжность = Ложь;
ВходящиеДанные.Начисления = Новый ТаблицаЗначений;
ВходящиеДанные.Начисления.Колонки.Добавить("Начисление");
ВходящиеДанные.Начисления.Колонки.Добавить("Размер");
Для Каждого Строка из Источник.ОсновныеНачисления Цикл
Если Строка.ФизическоеЛицо <> Источник.ФизическоеЛицо Тогда
Продолжить;
КонецЕсли;
Если Строка.Действие = Перечисления.ВидыДействияСНачислением.Прекратить Тогда
Продолжить;
КонецЕсли;
НовСтрока = ВходящиеДанные.Начисления.Добавить();
ЗаполнитьЗначенияСвойств(НовСтрока, Строка);
Если Строка.Действие = Перечисления.ВидыДействияСНачислением.Изменить ИЛИ Строка.Действие = Перечисления.ВидыДействияСНачислением.Начать Тогда
ВходящиеДанные.ИзменитьНачисления = Истина;
КонецЕсли;
КонецЦикла;
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Ссылка", Источник.Ссылка);
Запрос.Текст =
"ВЫБРАТЬ РАЗЛИЧНЫЕ
| РаботникиОрганизацииСрезПоследних.ПодразделениеОрганизации КАК ПодразделениеОрганизации,
| РаботникиОрганизацииСрезПоследних.Должность КАК Должность
|ИЗ
| РегистрСведений.РаботникиОрганизаций.СрезПоследних(&Период, Сотрудник = &Сотрудник И Регистратор <> &Ссылка) КАК РаботникиОрганизацииСрезПоследних";
Запрос.УстановитьПараметр("Период", Источник.ДатаНачала);
Запрос.УстановитьПараметр("Сотрудник", Источник.Сотрудник);
Выборка = Запрос.Выполнить().Выбрать();
Если Выборка.Следующий() Тогда
Если Выборка.ПодразделениеОрганизации <> Источник.Подразделение ИЛИ Выборка.Должность <> Источник.Должность Тогда
ВходящиеДанные.ИзменитьПодразделениеИДолжность = Истина;
КонецЕсли;
КонецЕсли;Текущую категорию ЕСВ сотрудника попытаемся определить из текущих данных регистра "ВзносыВФондыРаботниковОрганизаций" в событии "Перед выгрузкой" ПКС "КатегорияЕСВ":
Значение = Справочники.Налоги.ПустаяСсылка();
Запрос = Новый Запрос;
Запрос.Текст = "
|ВЫБРАТЬ РАЗЛИЧНЫЕ ПЕРВЫЕ 1
| ВзносыВФондыРаботниковОрганизацийСрезПоследних.Налог
|ИЗ
| РегистрСведений.ВзносыВФондыРаботниковОрганизаций.СрезПоследних(&Дата,) КАК ВзносыВФондыРаботниковОрганизацийСрезПоследних
|ГДЕ
| ВзносыВФондыРаботниковОрганизацийСрезПоследних.Организация = &Организация
| И ВзносыВФондыРаботниковОрганизацийСрезПоследних.Сотрудник = &Сотрудник
| И ВзносыВФондыРаботниковОрганизацийСрезПоследних.Налог НЕ В (&СписокНалогов)
|";
СписокНалогов = Новый СписокЗначений;
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничные);
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничныеИнвалиды50);
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничныеИнвалиды);
СписокНалогов.Добавить(Справочники.Налоги.ЕСВФОТБольничныеУТОГ);
Запрос.УстановитьПараметр("Дата", Источник.Дата);
Запрос.УстановитьПараметр("Организация", Источник.Организация);
Запрос.УстановитьПараметр("Сотрудник", Источник.Сотрудник);
Запрос.УстановитьПараметр("СписокНалогов", СписокНалогов);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Значение = Выборка.Налог;
КонецЦикла;
Если НЕ ЗначениеЗаполнено(Значение) Тогда
Значение = Справочники.Налоги.ЕСВФОТРаботники;
КонецЕсли;Документ "Увольнение из организации"
Самый простой вариант выгрузки. По прежнему обращаемся к табличной части документа и выгружаем его "построчно":
ВЫБРАТЬ
УвольнениеИзОрганизацийРаботникиОрганизации.Ссылка,
УвольнениеИзОрганизацийРаботникиОрганизации.Ссылка.Дата,
УвольнениеИзОрганизацийРаботникиОрганизации.Ссылка.Организация,
УвольнениеИзОрганизацийРаботникиОрганизации.Ссылка.Комментарий,
УвольнениеИзОрганизацийРаботникиОрганизации.ФизЛицо КАК ФизическоеЛицо,
УвольнениеИзОрганизацийРаботникиОрганизации.ДатаУвольнения,
УвольнениеИзОрганизацийРаботникиОрганизации.Сотрудник,
УвольнениеИзОрганизацийРаботникиОрганизации.СтатьяКЗОТ
ИЗ
Документ.УвольнениеИзОрганизаций.РаботникиОрганизации КАК УвольнениеИзОрганизацийРаботникиОрганизации
ГДЕ
УвольнениеИзОрганизацийРаботникиОрганизации.Ссылка.Проведен
И УвольнениеИзОрганизацийРаботникиОрганизации.Ссылка.Организация = &Организация
И &ДопУсловиеПКО "Увольнение"
Документ "Зарплата к выплате организации"
В правилах конвертации по умолчанию, выгружается в одноименный документ в Бухгалтерию 2.0, который, судя по всему, оставлен для перехода из версии 1.2.
В новой конфигурации "Бухгалтерия для Украины 2.0", для регистрации информации о суммах, которые должны быть выплачены сотрудникам, используются документы "Ведомость в банк" и "Ведомость в кассу" (в зависимости от типа выплаты). Оба документа имеют практически одинаковую структуру реквизитов. Во втором отсутствует реквизит "НомерЛицевогоСчета". В ЗиУП для регистрации информации о суммах служит один документ "Ведомость на выплату зарплаты", который может содержать выплаты как через банк, так и через кассу.
Значит, это будет выгрузка вида "один-к-двум", когда один документ в базе-источнике может соответствовать одновременно 2-м документам разного типа в базе-приемнике. Исходя из этого, мы можем использовать поиск по уникальному идентификатору.
Схема выгрузки будем следующая:
- Выгружаем документы "Ведомость на выплату зарплаты" за нужный период с отбором по реквизиту "Способ выплаты" табличной части РаботникиОрганизации (через кассу или через банк);
- В ПКО формируем во входящих данных структуру табличных частей (Взносы, ВзносыФОТ, НДФЛ, Зарплата, ЗарплатаПодробно и ФизическиеЛица) документа-приемника;
- Делаем запрос к таб. частям документа и выгружаем их с отбором в табличные части документа-приемника
//Алгоритм "Ведомость на выплату зарплаты в банк"
ВЫБРАТЬ РАЗРЕШЕННЫЕ
ЗарплатаКВыплатеОрганизаций.Ссылка,
ЗарплатаКВыплатеОрганизаций.Номер,
ЗарплатаКВыплатеОрганизаций.Дата,
ЗарплатаКВыплатеОрганизаций.Организация,
ЗарплатаКВыплатеОрганизаций.ПериодРегистрации,
ЗарплатаКВыплатеОрганизаций.ВидВыплаты КАК СпособВыплаты,
ЗарплатаКВыплатеОрганизаций.Комментарий,
ЗарплатаКВыплатеОрганизаций.ПодразделениеОрганизации КАК Подразделение
ИЗ
Документ.ЗарплатаКВыплатеОрганизаций КАК ЗарплатаКВыплатеОрганизаций
ГДЕ
ЗарплатаКВыплатеОрганизаций.Проведен
И ЗарплатаКВыплатеОрганизаций.Организация = &Организация
И ЗарплатаКВыплатеОрганизаций.РаботникиОрганизации.ВыплаченностьЗарплаты = ЗНАЧЕНИЕ(Перечисление.ВыплаченностьЗарплаты.Выплачено)
И ЗарплатаКВыплатеОрганизаций.РаботникиОрганизации.СпособВыплаты = ЗНАЧЕНИЕ(Перечисление.СпособыВыплатыЗарплаты.ЧерезБанк)
И &ДопУсловиеЗапрос который формирует все табличные части документа-приемника:
ВЫБРАТЬ РАЗЛИЧНЫЕ
ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.Сотрудник КАК Сотрудник
ПОМЕСТИТЬ ВтСотрудники
ИЗ
Документ.ЗарплатаКВыплатеОрганизаций.РаботникиОрганизации КАК ЗарплатаКВыплатеОрганизацийРаботникиОрганизации
ГДЕ
ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.ВыплаченностьЗарплаты = ЗНАЧЕНИЕ(Перечисление.ВыплаченностьЗарплаты.Выплачено)
И ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.СпособВыплаты = &СпособВыплаты
И ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.Ссылка = &Ссылка
;
ВЫБРАТЬ
ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.Сотрудник.ФизЛицо КАК ФизическоеЛицо,
ЕСТЬNULL(ЗарплатаКВыплатеОрганизацийПараметрыОплаты.Сумма,0) КАК КВыплате,
ЕСТЬNULL(ЗарплатаКВыплатеОрганизацийПараметрыОплаты.СуммаОкругления,0) КАК СуммаОкругления,
ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.НомерКарточки КАК НомерЛицевогоСчета,
ЗарплатаКВыплатеОрганизацийПараметрыОплаты.ПериодВзаиморасчетов,
ЗарплатаКВыплатеОрганизацийПараметрыОплаты.СчетУчета,
ЕСТЬNULL(ЗарплатаКВыплатеОрганизацийПараметрыОплаты.СуммаГрязными, 0) КАК СуммаГрязными
ПОМЕСТИТЬ СводнаяТаблица
ИЗ
Документ.ЗарплатаКВыплатеОрганизаций.РаботникиОрганизации КАК ЗарплатаКВыплатеОрганизацийРаботникиОрганизации
ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗарплатаКВыплатеОрганизаций.ПараметрыОплаты КАК ЗарплатаКВыплатеОрганизацийПараметрыОплаты
ПО ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.Сотрудник = ЗарплатаКВыплатеОрганизацийПараметрыОплаты.Сотрудник
И ЗарплатаКВыплатеОрганизацийПараметрыОплаты.Ссылка = &Ссылка
ГДЕ
ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.ВыплаченностьЗарплаты = ЗНАЧЕНИЕ(Перечисление.ВыплаченностьЗарплаты.Выплачено)
И ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.СпособВыплаты = &СпособВыплаты
И ЗарплатаКВыплатеОрганизацийРаботникиОрганизации.Ссылка = &Ссылка
;
////////////////////////////////////////////////////////////////////////////////
//ТЧ Взносы
ВЫБРАТЬ
Взносы.Налог,
Взносы.СтатьяНалоговойДекларации,
ЕСТЬNULL(Взносы.Результат,0) КАК Сумма,
Взносы.ПериодВзаиморасчетов
ИЗ
Документ.ЗарплатаКВыплатеОрганизаций.Взносы КАК Взносы
ГДЕ
Взносы.Сотрудник В (ВЫБРАТЬ Вт.Сотрудник из ВтСотрудники КАК Вт) И
Взносы.Ссылка = &Ссылка И
ЕСТЬNULL(Взносы.Результат,0) > 0
;
////////////////////////////////////////////////////////////////////////////////
//ТЧ ВзносыФОТ
ВЫБРАТЬ
ВзносыФОТ.Налог,
ВзносыФОТ.СтатьяНалоговойДекларации,
ЕСТЬNULL(ВзносыФОТ.Результат,0) КАК Сумма,
ВзносыФОТ.ПериодВзаиморасчетов
ИЗ
Документ.ЗарплатаКВыплатеОрганизаций.ВзносыФОТ КАК ВзносыФОТ
ГДЕ
ВзносыФОТ.Сотрудник В (ВЫБРАТЬ Вт.Сотрудник из ВтСотрудники КАК Вт) И
ВзносыФОТ.Ссылка = &Ссылка И
ЕСТЬNULL(ВзносыФОТ.Результат,0) > 0
;
////////////////////////////////////////////////////////////////////////////////
//ТЧ НДФЛ
ВЫБРАТЬ
НДФЛ.Сотрудник.Физлицо КАК Контрагент,
НДФЛ.ДоходНДФЛ,
НДФЛ.НалоговыйПериод,
НДФЛ.Доход,
ЕСТЬNULL(НДФЛ.Налог, 0) КАК Налог,
НДФЛ.ПериодВзаиморасчетов
ИЗ
Документ.ЗарплатаКВыплатеОрганизаций.НДФЛ КАК НДФЛ
ГДЕ
НДФЛ.Сотрудник В (ВЫБРАТЬ Вт.Сотрудник из ВтСотрудники КАК Вт) И
НДФЛ.Ссылка = &Ссылка И
ЕСТЬNULL(НДФЛ.Налог, 0) > 0
;
////////////////////////////////////////////////////////////////////////////////
//ТЧ Зарплата
ВЫБРАТЬ
СводнаяТаблица.ФизическоеЛицо,
СУММА(СводнаяТаблица.КВыплате) КАК КВыплате,
СводнаяТаблица.НомерЛицевогоСчета
ИЗ
СводнаяТаблица КАК СводнаяТаблица
СГРУППИРОВАТЬ ПО
СводнаяТаблица.ФизическоеЛицо,
СводнаяТаблица.НомерЛицевогоСчета
;
////////////////////////////////////////////////////////////////////////////////
//ТЧ ЗарплатаПодробно
ВЫБРАТЬ
СводнаяТаблица.ФизическоеЛицо,
СводнаяТаблица.ПериодВзаиморасчетов,
СводнаяТаблица.СчетУчета,
СводнаяТаблица.КВыплате,
СводнаяТаблица.СуммаГрязными,
СводнаяТаблица.СуммаОкругления
ИЗ
СводнаяТаблица КАК СводнаяТаблица
ГДЕ
СводнаяТаблица.КВыплате > 0
;
////////////////////////////////////////////////////////////////////////////////
//ТЧ ФизическиеЛица
ВЫБРАТЬ
СводнаяТаблица.ФизическоеЛицо
ИЗ
СводнаяТаблица КАК СводнаяТаблица
СГРУППИРОВАТЬ ПО
СводнаяТаблица.ФизическоеЛицо
;
////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ СводнаяТаблица;
УНИЧТОЖИТЬ ВтСотрудники
Событие "Перед выгрузкой" ПКО "ВедомостьНаВыплатуЗарплатыВБанк":
РежимЗаписи = "Проведение";
Выполнить(Алгоритмы.ВедомостьНаВыплатуЗПСформироватьВходящиеДанные);
Запросы.ВедомостьНаВыплатуЗарплатыТабЧасти.УстановитьПараметр("Ссылка", Источник.Ссылка);
Запросы.ВедомостьНаВыплатуЗарплатыТабЧасти.УстановитьПараметр("СпособВыплаты", Перечисления.СпособыВыплатыЗарплаты.ЧерезБанк);
МассивРезультатов = Запросы.ВедомостьНаВыплатуЗарплатыТабЧасти.ВыполнитьПакет();
Если НЕ МассивРезультатов[2].Пустой() Тогда
ВходящиеДанные.Взносы = МассивРезультатов[2].Выгрузить();
КонецЕсли;
Если НЕ МассивРезультатов[3].Пустой() Тогда
ВходящиеДанные.ВзносыФОТ = МассивРезультатов[3].Выгрузить();
КонецЕсли;
Если НЕ МассивРезультатов[4].Пустой() Тогда
ВходящиеДанные.НДФЛ = МассивРезультатов[4].Выгрузить();
КонецЕсли;
Если НЕ МассивРезультатов[5].Пустой() Тогда
ВходящиеДанные.Зарплата = МассивРезультатов[5].Выгрузить();
КонецЕсли;
Если НЕ МассивРезультатов[6].Пустой() Тогда
ВходящиеДанные.ЗарплатаПодробно = МассивРезультатов[6].Выгрузить();
КонецЕсли;
Если НЕ МассивРезультатов[7].Пустой() Тогда
ВходящиеДанные.ФизическиеЛица = МассивРезультатов[7].Выгрузить();
КонецЕсли;